QA32 ve QA33 raporlarına ZZ`li yeni alan eklenmesi.

1)Append the structure qals_d02 in se11 with the field you want to display
ZQM_QALS-ZZ_IRSALIYE

2)Append the same field in QALS table in se11. (to save you from dump on running QA32)
CI_QALS-ZZ_IRSALIYE

3) RQALVF14 programında CALL_LISTVIEWER_F14 performu başına enhancement ekle. (Program listesinden RQEEAL10 seçilebilir)

FORM call_listviewer_f14 USING  P_FIELDCAT_TAB TYPE SLIS_T_FIELDCAT_ALV
                                P_OBJECT_TAB TYPE TABLE.
""""""""""""""""""""""""""""""""""""""""""""""""""""""""$"$SE:(1) Form CALL_LISTVIEWER_F14, Start                                                                                                                   A
*$*$-Start: (1)----------------------------------------------------$*$*
ENHANCEMENT 1  ZQM_QA32_ADD_FIELD.    "active version
  IF sy-tcode EQ `QA32` OR sy-tcode EQ `QA33`.
    LOOP AT p_object_tab ASSIGNING FIELD-SYMBOL(<lfs_obj>).
      ASSIGN COMPONENT `MBLNR` OF STRUCTURE <lfs_obj> TO FIELD-SYMBOL(<lfs_mblnr>).
      ASSIGN COMPONENT `MJAHR` OF STRUCTURE <lfs_obj> TO FIELD-SYMBOL(<lfs_mjahr>).

      IF <lfs_mblnr> IS ASSIGNED AND <lfs_mjahr> IS ASSIGNED.
        SELECT SINGLE xblnr FROM mkpf INTO @DATA(lv_xblnr)
          WHERE mblnr EQ @<lfs_mblnr>
            AND mjahr EQ @<lfs_mjahr>.

        IF sy-subrc EQ 0.
          ASSIGN COMPONENT `ZZ_IRSALIYE` OF STRUCTURE <lfs_obj>
            TO FIELD-SYMBOL(<lfs_irsaliye>).
          IF <lfs_irsaliye> IS ASSIGNED.
            <lfs_irsaliye> = lv_xblnr.
          ENDIF.
        ENDIF.
      ENDIF.
      UNASSIGN: <lfs_mblnr>, <lfs_mjahr>, <lfs_irsaliye>.
      CLEAR lv_xblnr.
    ENDLOOP.
    UNASSIGN <lfs_obj>.
  ENDIF.
ENDENHANCEMENT.

*$*$-End:   (1)-----------------------------------------------------$*$*
  DATA:
    l_exit_caused_by_caller TYPE c,
    l_exit_caused_by_user   TYPE slis_exit_by_user,
    lt_exc                  TYPE TABLE OF alv_s_qinf,
    ls_exc                  TYPE alv_s_qinf.

  ls_exc-type = cl_salv_tooltip=>c_type_symbol.
  ls_exc-value = SYM_CHECK_MARK.
          .
          .
          .
4)RQALVF14 programında AKTUALISIEREN_F14 performu sonuna enhancement ekle. (Program listesinden RQEEAL10 seçilebilir)
    .
    .
    .
  CALL FUNCTION `STATUS_BUFFER_REFRESH`.

  FREE MEMORY ID `SUBMIT`.
  FREE MEMORY ID g_repid.
""""""""""""""""""""""""""""""$"$SE:(2) Form AKTUALISIEREN_F14, End                                                                                                                       A
*$*$-Start: (2)---------------------------------------------------$*$*
ENHANCEMENT 2  ZQM_QA32_ADD_FIELD.    "active version

  IF sy-tcode EQ `QA32` OR sy-tcode EQ `QA33`.
    IF NOT object_tab[] IS INITIAL.
      SELECT mblnr, mjahr, xblnr FROM mkpf INTO TABLE @DATA(lt_mkpf)
        FOR ALL ENTRIES IN @object_tab
        WHERE mblnr EQ @object_tab-mblnr
          AND mjahr EQ @object_tab-mjahr.
      SORT lt_mkpf BY mblnr mjahr.
    ENDIF.

    LOOP AT object_tab ASSIGNING FIELD-SYMBOL(<lfs_obj>).
      READ TABLE lt_mkpf ASSIGNING FIELD-SYMBOL(<lfs_mkpf>)
                         WITH KEY mblnr = <lfs_obj>-mblnr
                                  mjahr = <lfs_obj>-mjahr
                                  BINARY SEARCH.
      IF sy-subrc EQ 0.
        <lfs_obj>-zz_irsaliye = <lfs_mkpf>-xblnr.
      ENDIF.
      UNASSIGN: <lfs_mkpf>.
    ENDLOOP.
    UNASSIGN <lfs_obj>.
  ENDIF.

ENDENHANCEMENT.
*$*$-End:   (2)-------------------------------------------------------$*$*
ENDFORM.                               " AKTUALISIEREN_F14